ANL-926 Help!

[Med_Support]

foxworthywa

Hello all,
My lab is using an old MPC program on a new setup that includes the ANL-926 audio generator. The old program defines a tone as an output and controls it in the same way you would control any other output. I can’t get the ANL-926 to behave in the same way and I cannot find any documentation that allows my to simply turn on and turn off a tone for use as a conditioned stimulus.

I am new to MedPC programming and I’m completely lost – please help!

 

I’m attaching the segment of code which contains the tone. I would like to make the ANL-926 respond in place of “^TONE=12” and “^WHITENOISE=11” Your contribution to a struggling graduate student is greatly appreciated!!

Alex

\ OUTPUTS
^LIGHTCS=4
^HLIGHT=7
^DIPPER=6
^TONE=12
^WHITENOISE=11

S.S.1,

S1,
#R^MENTRY:ADD C--->S1

S.S.2,

S1,
#R^MENTRY:--->S2

S2,
1":IF C=0 [@TRUE,@FALSE]
@TRUE:IF B=0 [@TRUE,@FALSE]
@TRUE:Z1--->S2
@FALSE:--->S2
@FALSE:--->S3
S3,
0.01":SET C=0--->S2

S.S.3,

S1,
#START:--->S2

S2,
0.1":ON^HLIGHT,^WHITENOISE--->S3

S3,
#Z1:IF X=0 [@True,@False]
@True:SET X=30,Y=1/X*10000--->S4
@False:SET Y=1/X*10000--->S4
S4,
0.01":WITHPI = Y [@TRUE,@FALSE]
@TRUE:SET B=4;--->S5
@FALSE:--->S2
S5,
5":OFF^HLIGHT;ON^lightCS,^TONE;OFF^HLIGHT;SET B=1--->S6

S6,
10":ON^HLIGHT,^DIPPER;OFF^lightCS,^TONE;SET B=3--->S7

S7,
3.5":OFF^DIPPER;ADD R;SET B=0--->S3

[Med_Support]

Gary Bamberger

The ANL-926 is not controlled in the same way as a regular output.  There are special commands that are used in order to control the card.  Here is an example program:

S.S.1,
S1,
1": SET A = 1000;                   \ Frequency      = 1000 Hz
SET B = 100;                    \ Volume         = 100 dB
SET C = 10;                     \ Rise\Fall Time = 10 ms
SET D = 1000;                   \ Duration       = 1000 ms
---> S2

S2,
#START: ~InitANL926;~;              \ Reset ANL-926
~SetFreq(MG, BOX, A);~;     \ Initialize Frequency
~SetAmp(MG, BOX, B);~;      \ Initialize Amplitude
~SetRF(MG, BOX, C);~;       \ Initialize Rise\Fall Time
~SetDur(MG, BOX, D);~;      \ Initialize Duration
~OnFreq(MG, BOX, A);~;      \ Issue Starting Stimulus
---> S3

S3,
#K1: SET A = A + 200;               \ Increase Frequency
~OnFreq(MG, BOX, A);~ ---> S3
#K2: SET A = A - 200;               \ Decrease Frequency
~OnFreq(MG, BOX, A);~ ---> S3
#K3: SET A = 0;                     \ Select White Noise
~OnFreq(MG, BOX, A);~ ---> S3
#K4: SET A = 1000;                  \ Reset Frequency to 1000 Hz
~OnFreq(MG, BOX, A);~ ---> S3

 

S.S.2,
S1,
1": SHOW 1,FREQ,A, 2,AMP,B, 3,RF,C, 4,DUR,D ---> S1

There is a manual for the ANL-926 that explains all of the commands and how to use them.  Please contact support@med-associates.com if you need a copy of the manual.

[Author]

Posts